-- Stored Procedure: dbo.DbConfigUpdate
-- Bill Wunder

use admin
GO
SET QUOTED_IDENTIFIER ON 
GO
SET ANSI_NULLS ON 
GO

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[DbConfigUpdate]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[DbConfigUpdate]
GO

CREATE Procedure dbo.DbConfigUpdate
 @DatabaseName nvarchar(50),
 @IncludeDBScript varchar(5),
 @IncludeDataTypes varchar(5),
 @IncludeDefaults varchar(5),
 @IncludeFunctions varchar(5),
 @IncludeProcedures varchar(5),
 @IncludeRoles varchar(5),
 @IncludeRules varchar(5),
 @IncludeTables varchar(5),
 @IncludeTriggers varchar(5),
 @IncludeUsers varchar(5),
 @IncludeViews varchar(5)
AS

/******************************************************************************
** File: dbo.DbConfigUpdate.PRC
** Name: admin.dbo.DbConfigUpdate
** Desc: apply any changes made to the database archive config, 
**
** Auth: Bill Wunder
** Date: 7-25-2003
*******************************************************************************
** Change History
*******************************************************************************
** Date:  Author:  Description:
** -------- -------- ---------------------------------------
**    
*******************************************************************************/
SET NOCOUNT OFF

if db_id(@DatabaseName) is null
 begin
  Delete admin.dbo.ArchUtilDBConfig 
  where DatabaseName = @DatabaseName

  if @@rowcount = 1
   insert admin.dbo.ArchUtilChanges
    (SQLServerName
    , VSSItem
    , VSSParent
    , VSSItemType
    , DatabaseName
    , ChangeAction)
   values (@@servername
    , ''
    , ''
    , ''     
    , @DatabaseName
    , 'Delete Database Archive Configuration')
 end
else
 begin
  UPDATE admin.dbo.ArchUtilDBConfig 
  SET IncludeDBScript = @IncludeDBScript
   , IncludeDataTypes = @IncludeDataTypes
   , IncludeDefaults = @IncludeDefaults
   , IncludeFunctions = @IncludeFunctions
   , IncludeProcedures = @IncludeProcedures
   , IncludeRoles = @IncludeRoles
   , IncludeRules = @IncludeRules
   , IncludeTables = @IncludeTables
   , IncludeTriggers = @IncludeTriggers
   , IncludeUsers = @IncludeUsers
   , IncludeViews = @IncludeViews 
  WHERE DatabaseName = @DatabaseName 
  
  if @@rowcount = 1
   insert admin.dbo.ArchUtilChanges
    (SQLServerName
    , VSSItem
    , VSSParent
    , VSSItemType
    , DatabaseName
    , ChangeAction)
   values (@@servername
    , ''
    , ''
    , ''     
    , @DatabaseName
    , 'Change Database Archive Configuration')
  else
   begin
    -- data grid populated with a row for each db on server if if no row exists in table
    insert admin.dbo.ArchUtilDBConfig 
     (DatabaseName
     , IncludeDBScript
     , IncludeDataTypes
     , IncludeDefaults
     , IncludeFunctions
     , IncludeProcedures
     , IncludeRoles
     , IncludeRules
     , IncludeTables
     , IncludeTriggers
     , IncludeUsers
     , IncludeViews) 
    values (@DatabaseName
     , @IncludeDBScript
     , @IncludeDataTypes
     , @IncludeDefaults
     , @IncludeFunctions
     , @IncludeProcedures
     , @IncludeRoles
     , @IncludeRules
     , @IncludeTables
     , @IncludeTriggers
     , @IncludeUsers
     , @IncludeViews)

    insert admin.dbo.ArchUtilChanges
     (SQLServerName
     , VSSItem
     , VSSParent
     , VSSItemType
     , DatabaseName
     , ChangeAction)
    values (@@servername
     , ''
     , ''
     , ''     
     , @DatabaseName
     , 'Add Database Archive Configuration')
   end

 end
GO
SET QUOTED_IDENTIFIER ON 
GO
SET ANSI_NULLS ON 
GO